На диалоговом поле метод Modified

[lev]

вот, нашел в своем загашнике знаний
Как динамически изменять активность поля диалога:

Если перекрыть в вашем классе метод void dialogSelectCtrl() и произвести вызов метода dialog.allowUpdateOnSelectCtrl(true);
в перекрытом методе dialog(), то ваш перекрытый метод dialogSelectCtrl() будет вызываться каждый раз при получении фокуса
элементом ввода.

Вконце метода dialog() добавляете следующий код:

{
  ...
  dialog.allowUpdateOnSelectCtrl(true);
  this.dialogSelectCtrl();

  return dialog;
}

далее перекрываете метод dialogSelectCtrl(), в котором и обрабатываете ваши контролы. Например так:

public void dialogSelectCtrl()
{
    super();

    flag = dlgControlFlag.value();
    if(flag)
        dlgControlField.active(false);
    else
        dlgControlField.active(true);
}

[Gustav]

Цитата:

Сообщение от Poleax

тема закрыта. Нашел решение вопроса в Похожие темы метод Modified к stringControl

Да, Poleax... А темка-то - ваша же... Пора вам активировать свой блог (http://www.axforum.info/forums/blog.php?u=4016) и создать там хотя бы одно сообщение и записывать туда узелки на память с краткими комментариями.

Можно примерно так, как я пробую в этом сообщении: Gustav: Unsorted, или Записки DAX-дилетанта - II

[Poleax]

Цитата:

Сообщение от lev

вот, нашел в своем загашнике знаний
Как динамически изменять активность поля диалога:

Если перекрыть в вашем классе метод void dialogSelectCtrl() и произвести вызов метода dialog.allowUpdateOnSelectCtrl(true);
в перекрытом методе dialog(), то ваш перекрытый метод dialogSelectCtrl() будет вызываться каждый раз при получении фокуса
элементом ввода.
...

\Classes\RAssetReport
добавил методы модификации на поля:

void dateField_modified()
{
    ;
    info('dateField_modified');
    breakpoint;
}

void numberField_modified()
{
    ;
    info('numberField_modified');
    breakpoint;
}

переписал \Classes\RAssetReport\prompt

protected boolean prompt()
{
    Dialog      dlg;
    ;

    dlg = this.dialog();

//    dlg.run();
    dlg.doRun();
    this.dialogPostRun(dlg); 
    dlg.wait();

    if (dlg.closedOk())
        return this.getFromDialog();

    return false;
}

public void dialogPostRun(Dialog _dialog)
{
    ;
    _dialog.dialogForm().formRun().controlMethodOverload(true);
    _dialog.dialogForm().formRun().controlMethodOverloadObject(this);
}

при изменений полей даты документа или номера документа "Акт приемки оборудования (№ ОС-14)"
РЕАКЦИИ НИ КАКОЙ Не видит методы _modified

метод dialogSelectCtrl() бесполезен, так как он отрабатывает только один раз при открытии диалогового окна.
При изменении значения в поле, метод dialogSelectCtrl() даже не реагирует.

Как заставить видить _modified ?

Надо учесть что Classes\RAssetReport ни от кого не наследован.

[Gustav]

Цитата:

Сообщение от Poleax

\Classes\RAssetReport
добавил методы модификации на поля:

void dateField_modified()
{
    ;
    info('dateField_modified');
    breakpoint;
}

void numberField_modified()
{
    ;
    info('numberField_modified');
    breakpoint;
}

Такие методы надо писать, следуя определенным правилам, примерно так:

public boolean OKOFCode_modified()
{
    boolean             ret;
    FormStringControl   me = dialog.formRun().controlCallingMethod();
    ;

    ret = me.modified(); // как super()

    // далее наш функционал, который должен отрабатывать на modified

    return ret;
}

[Bishop]

Цитата:

Сообщение от Poleax

\Classes\RAssetReport
добавил методы модификации на поля:

void dateField_modified()
{
    ;
    info('dateField_modified');
    breakpoint;
}
 
void numberField_modified()
{
    ;
    info('numberField_modified');
    breakpoint;
}

при изменений полей даты документа или номера документа "Акт приемки оборудования (№ ОС-14)"

Извините за дурацкий вопрос...
А вы уверены, что созданные контролы на диалоге имеют имена "dateField" и "numberField" ?
В стандарте они создаются как "Fld1_1" и "Fld2_1". Соответственно, методы должны называться fld1_1_modified() и fld2_1_modified().

[Poleax]

Цитата:

Сообщение от Bishop

Извините за дурацкий вопрос...
А вы уверены, что созданные контролы на диалоге имеют имена "dateField" и "numberField" ?
В стандарте они создаются как "Fld1_1" и "Fld2_1". Соответственно, методы должны называться fld1_1_modified() и fld2_1_modified().

в AX 3.0 SP6 \Classes\RAssetReport\classDeclaration

    DialogField             dateField;
    DialogField             numberField;

Не наблюдаю "Fld1_1" и "Fld2_1"

[Bishop]

Цитата:

Сообщение от Poleax

в AX 3.0 SP6 \Classes\RAssetReport\classDeclaration

    DialogField             dateField;
    DialogField             numberField;

Не наблюдаю "Fld1_1" и "Fld2_1"

А вы посмотрите на форме диалога по правой кнопке в Настройках - увидите совсем другие имена...
dateField и numberField - названия переменных, а названия контролов совсем другие.
Посмотрите также методы dialog.addField() и dialogField.fieldName() - все станет ясно...

[Poleax]

Цитата:

Сообщение от Bishop

А вы посмотрите на форме диалога по правой кнопке в Настройках - увидите совсем другие имена...
dateField и numberField - названия переменных, а названия контролов совсем другие.
Посмотрите также методы dialog.addField() и dialogField.fieldName() - все станет ясно...

Ты абсолютно прав, чет я запарился уже

[Gustav]

Цитата:

Сообщение от Bishop

В стандарте они создаются как "Fld1_1" и "Fld2_1". Соответственно, методы должны называться fld1_1_modified() и fld2_1_modified().

Вспомнил свою цитату:

Цитата:

Сообщение от Gustav

Можно перейти от fld5_1 к "нормальному" названию поля типа "Kontragent", создав переменную контрола соответствующего типа, и тогда метод приобретет более осмысленное название типа Kontragent_modified(). Соответственно, никаких проблем с последующим добавлением полей в серединку не возникнет. Делал такое в Ax 3.0 sp4.

Там обещал выложить, а здесь-таки выложу:

static void Job220(Args _args)
{
    Dialog              dialog = new Dialog('Наш диалог');

    FormStringControl   fscOKOFCode;
    FormIntControl      ficLifeTime;

    DialogField         fieldOKOFCode;
    DialogField         fieldLifeTime;
    ;

    fieldOKOFCode   = dialog.addField(Types::String,'ОКОФ');
    fieldLifeTime   = dialog.addField(Types::Integer, 'Срок амортизации');

    fscOKOFCode     = fieldOKOFCode.fieldControl();
    ficLifeTime     = fieldLifeTime.fieldControl();

    fscOKOFCode.name('OKOFCode');
    ficLifeTime.name('LifeTime');

    dialog.doInit();

    dialog.formRun().controlMethodOverload( true );
    dialog.formRun().controlMethodOverloadObject( new KKu_TestForPoleax( dialog ));
    // KKu_TestForPoleax - класс, содержащий метод OKOFCode_modified

    dialog.run();

    // опытным путём было установлено, что здесь еще раз необходима инициализация переменных,
    // чтобы дальше ими свободно оперировать
    fscOKOFCode = dialog.formRun().design().controlName('OKOFCode');
    ficLifeTime = dialog.formRun().design().controlName('LifeTime');

    if(dialog.closedOk())
    {
        box::info(strFmt('ОКОФ: %1, Срок: %2', fscOKOFCode.text(), ficLifeTime.value()));
    }
}

Создайте у себя класс KKu_TestForPoleax:

class KKu_TestForPoleax
{
    Dialog dialog;
}

void new(Dialog _dialog)
{
    ;
    dialog = _dialog;
}

public boolean OKOFCode_modified()
{
    boolean             ret;
    FormStringControl   me = dialog.formRun().controlCallingMethod();
    ;

    ret = me.modified(); // как super()

    box::info('Привет, Poleax! Вон оно, оказывается, как надо было!');

    return ret;
}

и потом запустите вышеуказанный Job220

[Gustav]

Всё! ПолучИте законченный пример - джоб и класс к нему (см. выше).